home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Wonky Flux Batch 2019 02
/
Wonky_Flux_Batch_2019-02.zip
/
Wonky Flux Batch 2019-02
/
073 - ProSEL 3.3.dsk
/
I.P.PLUS.bas
< prev
next >
Wrap
BASIC Source File
|
2019-02-17
|
5KB
|
129 lines
10 REM INSTALL.PROSEL for ][+
20 IF PEEK(176) >30 THEN STOP
30 PRINT CHR$(4)"BLOAD/FLOPPY/COMMANDS/COPY,TCMD,A$4000": CALL 4 *4096
40 LOMEM: 6 *4096:N = 51: DIM DT$(N),DL$(N),DF$(N)
50 PRINT CHR$(12): HOME
60 PF$ = "/FLOPPY/":CO$ = CHR$(4) +"COPY" +PF$:CE$ = CHR$(4) +"COPY/EXTRAS/"
70 PRINT TAB( 6)"PROSEL INSTALLATION PROGRAM": PRINT
80 PRINT : PRINT "Please give the volume name of the"
90 PRINT "volume that is to receive PROSEL. Just"
100 PRINT "press RETURN to accept the name shown:": PRINT
110 DP$ = "/HARD1/"
120 PRINT DP$;: FOR I = 1 TO LEN(DP$): PRINT CHR$(8);: NEXT
130 INPUT "";NW$: IF NW$ < >"" THEN DP$ = NW$
140 IF LEFT$(DP$,1) < >"/" THEN DP$ = "/" +DP$
150 IF RIGHT$(DP$,1) < >"/" THEN DP$ = DP$ +"/"
160 ONERR GOTO 1230
170 PRINT CHR$(4)"PREFIX"DP$
180 POKE 216,0
190 PRINT : PRINT "Install 40, 80 column or Videoterm"
200 INPUT "version? (40/80/VT):";V$
210 IF V$ < >"40" AND V$ < >"80" AND V$ < >"VT" AND V$ < >"vt" THEN 190
220 GOSUB 740: REM Read destination directory
230 IF NOT SY THEN 320
240 SY$ = DF$(SY)
250 PRINT CHR$(4)"BSAVE YYYYYYYY,A$2000,L10"
260 PRINT CHR$(4)"UNLOCK"SY$
270 IF BA >0 THEN PRINT CHR$(4)"UNLOCK BASIC.SYSTEM"
280 PRINT CHR$(4)"COPY"SY$",XXXXXXXX"
290 PRINT CHR$(4)"DELETE"SY$
300 PRINT CHR$(4)"DELETE YYYYYYYY"
310 IF SY$ = "BASIC.SYSTEM " THEN SY = 0: PRINT CHR$(4)"DELETE XXXXXXXX"
320 PRINT "Installing PROSEL"
330 IF PD THEN 350
340 PRINT CO$"PRODOS,PRODOS"
350 PRINT CO$"PROSEL.SYSTEM,PROSEL.SYSTEM"
360 PRINT CO$"PROSEL."V$",PROSEL"
370 PRINT "Copying BASIC.SYSTEM"
380 PRINT CO$"BASIC.SYSTEM,BASIC.SYSTEM"
390 PRINT CHR$(4)"CREATE UTIL"
400 PRINT CHR$(4)"PREFIX UTIL"
410 PRINT "Installing disk utilities"
420 PRINT CO$"RECOVER,RECOVER"
430 PRINT CO$"COPY,COPY"
440 PRINT CO$"BLOCK.WARDEN,BLOCK.WARDEN"
450 PRINT CO$"INFO.DESK,INFO.DESK"
460 PRINT CO$"FIND.FILE,FIND.FILE"
470 PRINT CO$"UNI.FORMAT,UNI.FORMAT"
480 PRINT : PRINT "Please insert the disk /EXTRAS"
490 PRINT "and hit a key."
500 GET A$: PRINT
510 ONERR GOTO 480
520 PRINT CE$"BACKUP.PLUS,BACKUP"
530 PRINT CE$"RESTORE.PLUS,RESTORE"
540 PRINT CE$"CAT.DOCTOR.VT,CAT.DOCTOR"
550 PRINT CE$"PROSEL.ED.VT,PROSEL.ED"
560 PRINT CE$"MR.FIXIT,MR.FIXIT"
570 PRINT CE$"SCAVENGE,SCAVENGE"
580 PRINT CE$"SET.DATE,SET.DATE"
590 PRINT CE$"PASSWORD,PASSWORD"
600 PRINT CE$"PROSEL.CYCLER,PROSEL.CYCLER"
610 POKE 216,0
620 FOR I = 48946 TO 48946 + PEEK(48945)
630 FOR J = 5 TO 7
640 IF INT( PEEK(I)/16) < >J THEN 680
650 POKE 8192,76: POKE 8193,0: POKE 8194,J +12 *16
660 PRINT CHR$(4)"CREATE BOOT.S";J;",TSYS"
670 PRINT CHR$(4)"BSAVE BOOT.S";J;",TSYS,A$2000,L3"
680 NEXT J,I
690 PRINT CHR$(4)"PREFIX"DP$
700 IF SY THEN PRINT CHR$(4)"RENAME XXXXXXXX,"SY$
710 IF DL$(SY) = "*" THEN PRINT CHR$(4)"LOCK";SY$
720 PRINT CHR$(4)"-PROSEL.SYSTEM"
730 END
740 REM Read destination directory
750 POKE 48655,0
760 ONERR GOTO 1250
770 PRINT CHR$(4)"OPEN"DP$",TDIR"
780 PRINT CHR$(4)"READ"DP$
790 INPUT A$,A$,A$
800 I = 0: ONERR GOTO 940
810 INPUT A$: IF NOT LEN(A$) THEN 950
820 I = I +1:A$ = LEFT$(A$,20): IF I >N THEN 1250
830 DT$(I) = RIGHT$(A$,3):DL$(I) = LEFT$(A$,1):DF$(I) = MID$ (A$,2,16)
840 IF DF$(I) = "PROSEL.SYSTEM " THEN 980
850 IF DF$(I) = "PROSEL " THEN 980
860 IF DF$(I) = "XXXXXXXX " OR DF$(I) = "YYYYYYYY " THEN 1090
870 IF (SY >0) OR (DT$(I) < >"SYS") THEN 900
880 FOR J = 2 TO 16 -7: IF MID$ (DF$(I),J,7) = ".SYSTEM" THEN SY = I
890 NEXT J
900 IF DF$(I) = "BASIC.SYSTEM " THEN BA = 1
910 IF DF$(I) = "PRODOS " THEN PD = 1
920 IF DF$(I) = "UTIL " THEN PRINT CHR$(4)"UNLOCK"DP$"UTIL": PRINT CHR$(4)"RENAME"DP$"UTIL,"DP$"UTILXXX"
930 GOTO 810
940 CALL 62248: ONERR GOTO 1250
950 DN = I: PRINT CHR$(4)"CLOSE"DP$
960 POKE 216,0: IF DN >N -5 THEN 1160
970 RETURN
980 GOSUB 950: HOME
990 PRINT : PRINT "PROSEL already exists on ";DP$
1000 PRINT : PRINT "You should either delete all PROSEL"
1010 PRINT "related files on ";DP$;" and"
1020 PRINT "run this program again, or you should"
1030 PRINT "run INSTALL.REVISN instead. The"
1040 PRINT "INSTALL.REVISN program just modifies"
1050 PRINT "the PROSEL file and retains the present"
1060 PRINT "application specifications. It does"
1070 PRINT "not copy any other files."
1080 GOTO 1280
1090 GOSUB 950: HOME
1100 PRINT "This program creates scratch files"
1110 PRINT "XXXXXXXX and YYYYYYYY. One of these"
1120 PRINT "names is now on your ";DP$
1130 PRINT "directory. You must rename it and"
1140 PRINT "run this program again."
1150 GOTO 1280
1160 HOME
1170 PRINT "The directory of ";DP$
1180 PRINT "is too full for operation of the"
1190 PRINT "installation program. You must get"
1200 PRINT "rid of some files on the main directory"
1210 PRINT "and rerun this program."
1220 GOTO 1280
1230 HOME
1240 PRINT "Volume ";DP$;" not found.": GOTO 1280
1250 POKE 49044,0: PRINT CHR$(4)"CLOSE"
1260 POKE 640,173: POKE 641,15: POKE 642,190: POKE 643,76: POKE 644,12: POKE 645,190
1270 IF PEEK(48655) THEN CALL 640
1280 PRINT : PRINT "INSTALLATION ABORTED"
1290 NEW : END